tkmind_go/ui/goose2/justfile

# Derive a stable port from the working directory so the same worktree
# always gets the same port.
vite_port := `python3 -c "import hashlib,os; h=int(hashlib.sha256(os.getcwd().encode()).hexdigest(),16); print(10000 + h % 55000)"`

# Default recipe
default:
    @just --list

# ── Dev Environment ──────────────────────────────────────────

# Install dependencies
setup:
    pnpm install
    cd src-tauri && cargo build

# ── Build & Check ────────────────────────────────────────────

# Run all checks (lint, format, typecheck, file sizes)
check:
    pnpm check
    pnpm typecheck

# Format code
fmt:
    pnpm format
    cd src-tauri && cargo fmt

# Check formatting without modifying
fmt-check:
    pnpm exec biome format .
    cd src-tauri && cargo fmt --check

# Run clippy on Tauri backend
clippy:
    cd src-tauri && cargo clippy -- -D warnings

# Build the frontend
build:
    pnpm build

# Check Tauri Rust formatting
tauri-fmt-check:
    cd src-tauri && cargo fmt --check

# Check Tauri Rust types
tauri-check:
    cd src-tauri && cargo check

# Full CI gate
ci: check clippy test build tauri-check

# ── Test ─────────────────────────────────────────────────────

# Run unit/component tests
test:
    pnpm test

# Run tests in watch mode
test-watch:
    pnpm test:watch

# Run tests with coverage
test-coverage:
    pnpm test:coverage

# Run E2E smoke tests (builds first)
test-e2e:
    pnpm test:e2e:smoke

# Run all E2E tests (builds first)
test-e2e-all:
    pnpm test:e2e

# ── Run ──────────────────────────────────────────────────────

# Start the desktop app in dev mode
dev:
    #!/usr/bin/env bash
    set -euo pipefail

    VITE_PORT={{ vite_port }}
    export VITE_PORT
    PROJECT_DIR=$(pwd)
    TAURI_CONFIG="{\"build\":{\"devUrl\":\"http://localhost:${VITE_PORT}\",\"beforeDevCommand\":{\"script\":\"cd ${PROJECT_DIR} && exec pnpm exec vite --port ${VITE_PORT} --strictPort\",\"cwd\":\".\",\"wait\":false}}}"

    # In worktrees, generate a labeled icon so you can tell instances apart
    if git rev-parse --is-inside-work-tree &>/dev/null; then
        GIT_DIR=$(git rev-parse --git-dir)
        if [[ "$GIT_DIR" == *".git/worktrees/"* ]]; then
            BRANCH_NAME=$(git rev-parse --abbrev-ref HEAD)
            WORKTREE_LABEL="${BRANCH_NAME##*/}"

            ICON_DIR="$(pwd)/src-tauri/target/dev-icons"
            mkdir -p "$ICON_DIR"
            DEV_ICON="$ICON_DIR/icon.icns"

            if swift scripts/generate-dev-icon.swift src-tauri/icons/icon.icns "$DEV_ICON" "$WORKTREE_LABEL"; then
                echo "🌳 Worktree: ${WORKTREE_LABEL}"
                TAURI_CONFIG=$(python3 -c "import json,sys; a=json.loads(sys.argv[1]); a['bundle']={'icon':['$DEV_ICON']}; print(json.dumps(a))" "$TAURI_CONFIG")
            fi
        fi
    fi

    pnpm tauri dev --features app-test-driver --config "$TAURI_CONFIG"

# Start the desktop app with dev config
dev-debug:
    #!/usr/bin/env bash
    set -euo pipefail

    VITE_PORT={{ vite_port }}
    export VITE_PORT
    EXTRA_CONFIG="--config {\"build\":{\"devUrl\":\"http://localhost:${VITE_PORT}\",\"beforeDevCommand\":{\"script\":\"exec ./node_modules/.bin/vite --port ${VITE_PORT} --strictPort\",\"cwd\":\"..\",\"wait\":false}}}"

    # In worktrees, generate a labeled icon so you can tell instances apart
    if git rev-parse --is-inside-work-tree &>/dev/null; then
        GIT_DIR=$(git rev-parse --git-dir)
        if [[ "$GIT_DIR" == *".git/worktrees/"* ]]; then
            BRANCH_NAME=$(git rev-parse --abbrev-ref HEAD)
            WORKTREE_LABEL="${BRANCH_NAME##*/}"

            ICON_DIR="$(pwd)/src-tauri/target/dev-icons"
            mkdir -p "$ICON_DIR"
            DEV_ICON="$ICON_DIR/icon.icns"

            if swift scripts/generate-dev-icon.swift src-tauri/icons/icon.icns "$DEV_ICON" "$WORKTREE_LABEL"; then
                echo "🌳 Worktree: ${WORKTREE_LABEL}"
                EXTRA_CONFIG="$EXTRA_CONFIG --config {\"bundle\":{\"icon\":[\"$DEV_ICON\"]}}"
            fi
        fi
    fi

    pnpm tauri dev --config src-tauri/tauri.dev.conf.json $EXTRA_CONFIG

# Start only the frontend dev server
dev-frontend:
    pnpm dev

# Kill the dev process (if running)
kill:
    #!/usr/bin/env bash
    set -euo pipefail

    VITE_PORT={{ vite_port }}
    PID=$(lsof -ti :"$VITE_PORT" 2>/dev/null | head -1) || true

    if [[ -z "$PID" ]]; then
        echo "No process found on port $VITE_PORT"
        exit 0
    fi

    PROC_NAME=$(ps -p "$PID" -o comm= 2>/dev/null) || true
    if [[ "$PROC_NAME" != "node" ]]; then
        echo "Process on port $VITE_PORT is '$PROC_NAME', not 'node' — refusing to kill"
        exit 1
    fi

    echo "Killing node (PID $PID) on port $VITE_PORT"
    kill -9 "$PID"

# ── Utilities ────────────────────────────────────────────────

# Clean build artifacts
clean:
    cd src-tauri && cargo clean
    rm -rf dist
    rm -rf node_modules

# Cherry-pick commits from the goose2 repo into ui/goose2/
cherry-pick-goose2 *ARGS:
    git fetch goose2
    git format-patch -1 {{ARGS}} --stdout | git am --directory=ui/goose2